Deus Ex Alpha

~Snakey~ wrote:How to make a turret which fires a projectile (Like a fire turret or something)

A weapon which fires a projectile which, when it hits a player, halves their drawscale and also their health, but if their health is an odd number, it kills them. I want the drawscale effect to wear off when the player dies.

I made an electro dagger, I want the projectile to emit electricity

I want to make an electro gun that focuses the electricity emitter into a single beam.

A gun that fires a rocket which, when it hits a surface, explodes releasing gas that, if it hits a player, the player has a specified amount of time before dying (say, 1 minute) unless they find a certain pickup in this time.

I want to make pickups that you walk over and they activate as you touch them, Like in Timesplitters 2.

I want to make a special multitool that, when you aim it at a mover from a certain distance, it opens the mover. I also want the Multitool rays to appear as you do this.

A grenade that summons the effects of all 3 grenades (EMP, Gas and LAM) with the EMP blast having the biggest radius, the gas epxlosion having half the radius of this, and the LAM explosion having the smallest radius.

I want to make a Stealth kit pickup, which when you use it, it gives you certain augs and weapons, also changing your skin.

I made a pickup that adds augs in multiplayer when you use it, I want it to kill the aug that takes up the specified aug slot that the pickup recquires as you use it.

I also have a problem with a weapon I made, I made a custom skin for it, but in pickupview the skin doesn't fit properly. How do I make the skin fit? (I assume it has something to do with flags)

A few more things I need to know, but I can't remember them at the moment.

And please, reply to this topic. I don't want this to sink to the bottom of the page like all my other mod problem topics. I would appreciate any help you have to offer. Thank you.

~Snakey~ wrote:I want to make an electro gun that focuses the electricity emitter into a single beam.

Code: Select all

<s> and </s>

~Snakey~ wrote:I want to make a Stealth kit pickup, which when you use it, it gives you certain augs and weapons, also changing your skin.

~[A]tomsk~ wrote:My friend experimented with ecstasy in Deus Ex, it changes the hue and music to only the client user

A gun that fires a rocket which, when it hits a surface, explodes releasing gas that, if it hits a player, the player has a specified amount of time before dying (say, 1 minute) unless they find a certain pickup in this time.

~Snakey~ wrote:I cannot be bothered to look, link please?

~[A]Daedalus~ wrote:

~Snakey~ wrote:I cannot be bothered to look, link please?

I recommend you to play this mod. I like it a lot.
http://www.deusex-machina.com/cassandra-project/

~Snakey~ wrote:

~[A]Daedalus~ wrote:

~Snakey~ wrote:I cannot be bothered to look, link please?

I recommend you to play this mod. I like it a lot.
http://www.deusex-machina.com/cassandra-project/

Can't find a download link on the site

Snakey wrote:Decided to revive the mod for a map I'm currently making and I never did get any of these problems solved, could anyone provide any further help? It'd mean alot.

Code: Select all

function PostBeginPlay()
{
   Super.PostBeginPlay();

   zapTimer = 0;
   emitter = Spawn(class'ElectricityEmitter', Self);
   if (emitter != None)
   {
      emitter.bFlicker = False;
      /*this line below is the bit you want to change*/
      emitter.randomAngle = 1024;
            emitter.damageAmount = HitDamage;
      emitter.TurnOff();
      emitter.Instigator = Pawn(Owner);
   // don't let NPC geps lock on to targets
   if ((Owner != None) && !Owner.IsA('DeusExPlayer'))
      bCanTrack = False;
   }
}

However, if you want it to work in MP, you'll need to borrow some of the Hejuka Path(Spelling...?) code, which I can put up here too =)

I also have a problem with a weapon I made, I made a custom skin for it, but in pickupview the skin doesn't fit properly. How do I make the skin fit? (I assume it has something to do with flags)

Snakey wrote:I want to make a Stealth kit pickup, which when you use it, it gives you certain augs and weapons, also changing your skin.

Code: Select all

//=============================================================================
// StealthPickup.
//=============================================================================
class StealthPickup extends DeusExPickup;

state Activated
{
   local DeusExWeapon DXW;
   function Activate()
   {
      // YEY!
   }
   function BeginState()
   {
      local DeusExPlayer Player;
      
      Super.BeginState();

      Player = DeusExPlayer(Owner);
      if (Player != None)
      {
         // Let's make him look like Alex Jacobson.
         // You can set multiskins from [0] to [7], also you can set mesh and other stuff:
         // just hit "display" in default properties of NPC in UnrealEd and you will understand.
         Player.MultiSkins[1]=Texture'AlexJacobsonTex2';
         Player.MultiSkins[2]=Texture'AlexJacobsonTex1';
         // Let's give him cloak and healing aug (easy!):
         Player.AugmentationSystem.GivePlayerAugmentation(class'AugCloak');
         Player.AugmentationSystem.GivePlayerAugmentation(class'AugHealing');
         // Let's give him some weapons (crossbow and knife).
         DXW=Spawn(class'DeusEx.WeaponMiniCrossbow'); // <-- this spawns it somewhere
         DXW.Frob(Player, None); // <-- this forces player "grab" spawned thing, no matter where it is
         DXW=Spawn(class'DeusEx.WeaponCombatKnife');
         DXW.Frob(Player, None);
      }
      UseOnce();
   }
Begin:
}

defaultproperties
{
    maxCopies=1
    bCanHaveMultipleCopies=False
    bActivatable=True
    ItemName="Stealth pickup"
    ItemArticle="a"
    PlayerViewOffset=(X=30.00,Y=0.00,Z=-12.00),
    PlayerViewMesh=LodMesh'DeusExItems.AdaptiveArmor'
    PickupViewMesh=LodMesh'DeusExItems.AdaptiveArmor'
    ThirdPersonMesh=LodMesh'DeusExItems.AdaptiveArmor'
    Icon=Texture'DeusExUI.Icons.BeltIconArmorAdaptive'
    largeIcon=Texture'DeusExUI.Icons.LargeIconArmorAdaptive'
    largeIconWidth=35
    largeIconHeight=49
    Description="Stealth pickup does picking at agents that pick it up (add some random crap if you intend to use it in singlePlayer)."
    beltDescription="Stealth pickup"
    Mesh=LodMesh'DeusExItems.AdaptiveArmor'
    CollisionRadius=11.50
    CollisionHeight=13.81
    Mass=30.00
    Buoyancy=20.00
}

Code: Select all

function ProcessTraceHit(Actor Other, Vector HitLocation, Vector HitNormal, Vector X, Vector Y, Vector Z)
{
    local int i;
    local DeusExPlayer PlayerOwner;
   
if (Other==None)
{
  HitNormal = -X;
  HitLocation = Owner.Location + X*10000.0;
 }
PlayerOwner = DeusExPlayer(Owner);
 if (PlayerOwner !=None)
 PlayerOwner.ClientInstantFlash( -0.4, vect(450, 190, 650));
 SpawnEffect(HitLocation, Owner.Location);

  if ( (Other !=self) && (Other !=Owner) && (Other !=None) )
{
if ( Role == ROLE_Authority )
 Other.TakeDamage(HitDamage, Pawn(Owner), HitLocation, Vect(0,0,0), 'Shocked');
// Other.TakeDamage(HitDamage, Pawn(Owner), HitLocation, Vect(0,0,0), 'EMP'); This is optional, makes the player take damage to their EMP too.
}
}

function SpawnEffect(vector HitLocation, vector SmokeLocation)
{
   local Tazerbeam Smoke,Shock;
   local Vector DVector;
   local int NumPoints;
   local rotator SmokeRotation;
   local Vector NewRot;

  DVector = HitLocation - SmokeLocation;
  NumPoints = VSize(DVector)/10.0;
   if ( NumPoints < 1)
       return;
 SmokeRotation = rotator(DVector);
 SmokeRotation.roll = Rand(6553595);
 
 Smoke = Spawn(class'TazerBeam',,,SmokeLocation,SmokeRotation);
 Smoke.MoveAmount = DVector/NumPoints;
 Smoke.NumPuffs = NumPoints - 1;
}

Code: Select all

class TazerBeam extends Effects;

var vector MoveAmount;
var int NumPuffs;

replication
{
   // Things the server should send to the client.
   unreliable if( Role==ROLE_Authority )
      MoveAmount, NumPuffs;
}

simulated function Tick( float DeltaTime )
{
   if ( Level.NetMode  != NM_DedicatedServer )
   {
      ScaleGlow = (Lifespan/Default.Lifespan) * 1.0;
      AmbientGlow = ScaleGlow * 210;
   }
}

simulated function PostBeginPlay()
{
      SetTimer(0.001, false);
}

simulated function Timer()
{
   local TazerBeam r;
   
   if (NumPuffs>0)
   {
      r = Spawn(class'Tazerbeam',,,Location+MoveAmount);
      r.RemoteRole = ROLE_None;
      r.NumPuffs = NumPuffs -1;
      r.MoveAmount = MoveAmount;
   }
}

defaultproperties
{
     Physics=PHYS_Rotating
     LifeSpan=2.000000
     DrawType=DT_Mesh
     Style=STY_Translucent
     Mesh=LodMesh'DeusExItems.LaserBeam'
     DrawScale=1.000000
     bUnlit=True
     bParticles=True
     CollisionRadius=0.000000
     CollisionHeight=0.000000
     LightType=LT_Steady
     LightBrightness=255
     LightHue=128
     LightRadius=2
     bBounce=True
     bFixedRotationDir=True
     RotationRate=(Roll=2000000000)
     DesiredRotation=(Roll=20000)
     MultiSkins(0)=FireTexture'Effects.Electricity.WEPN_NESword_SFX'
}